Mobiclic 48/MOBICLIC 48.ISO/pc/DATA/SHARED/COMMUNS.CST/00003_Script_gestion de la navigation

Text File | 2002-09-18 | 4KB | 171 lines

-------------------------------------------------------------------
--------------------- GESTION DE LA NAVIGATION --------------------
-------------------------------------------------------------------

global gModule
global chemin  -- chemin    : chemin d'accΦs complet au niveau du sommaire
global volumeOn
global touchesOn  -- touchesOn : controle l'activation des raccourcis clavier
global gMyParent
global gNavMode
global gLastMovies

-- navigation entre films
on acces
  set n = the paramCount
  if n > 0 then
    initFilm
    gLastMovie = 0
    set nom = chemin
    if n > 1 then
      -- chemin d'accΦs a ΘtΘ envoyΘ sous forme de plusieurs paramΦtres
      repeat with i=1 to n
        if the machineType = 256 then
          set nom = nom & param(i) & "\"
        else
          set nom = nom & param(i) & ":"
        end if
      end repeat
      delete char(the number of chars of nom) of nom
    else
      -- chemin d'accΦs a ΘtΘ envoyΘ sous forme d'un seul paramΦtre
      if offset(":",param(1)) = 0 and offset("\",param(1)) = 0 then
        -- seulement un nom de fichier a ΘtΘ envoyΘ
        set nom = param(1)
      else
        -- un chemin d'accΦs a ΘtΘ envoyΘ
        set n = param(1)
        set nom = nom & nomDos(n)
      end if
    end if
    put "AccΦs au film : " & nom
    set nom=nom & ".dir"
    go to movie nom
    niveauSon
  end if
end

on initFilm
  cursor 4
  updateStage
  sound close 2
  sound close 3
  sound close 4
end

-- retour au sommaire
on mainWindow
  initFilm
  go to movie chemin & "menu"
  put "Ouverture sommaire α " & the time
  cursor -1
  sprite(115).member = member "vitrine"
  niveauSon
end

-- retour au sommaire rubrique
on somRub
  initFilm
  case gModule of
    1 : acces ("prom","prom01")
    2 : acces ("com","com01")
  end case
  cursor -1
  sprite(114).member = member "debRub"
  niveauSon
end

-- retour au film precedent
on precedent
  updateStage
  sound close 2
  sound close 3
  sound close 4
  gNavMode = #Nav
  lastmovie = gLastMovies[gLastMovies.count]
  if lastmovie = "menu.dir" then
    go to movie chemin & "menu"
  else if lastmovie = "prom01.dir" then
    go to movie "prom01"
  else if lastmovie = "com01.dir" then
    go to movie "com01"
  else
    go to movie gLastMovies[gLastMovies.count]
  end if
  gLastMovies.deleteAt(gLastMovies.count)

  niveauSon
end

-- quitter utilitaire
on exitUtil
  case gMyParent of
    0:
      --quitter
      if the optionDown=1 then
        closeXlib
        quit
      else
        sound close 3
        acces("communs","generic")
      end if
    1:
      -- retour sommaire Mobiclic
      touchesOn=1
      sound close 3
      go to movie chemin & "sommaire"
    2:
      -- retour sommaire Toboclic
      touchesOn=1
      sound close 3
      go to movie chemin & "sommaire"
  end case
end

-------------------------------------------------------------------
------------------------ GESTION DU CLAVIER -----------------------
-------------------------------------------------------------------

-- gestion de la navigation par flΦches
on keyDown
  if touchesOn=1 then
    set k = the keyCode
    set nomCh="shortcuts"
  end if
  repeat with i = 1 to the number of lines of field nomCh
    if k = value(word 1 of line i of field nomCh) then
      set menuMsg = word 2 of line i of field nomCh
      -- annulation raccourci clavier selon activation dans le menu
      case menuMsg of
        "precedent": -- appui sur flΦche gauche
          set liste=value(line 1 of field "Nav")
          if getAt(liste,1)=0 then
            put empty into menuMsg
            exit repeat
          end if
        "suivant": -- appui sur flΦche gauche
          set liste=value(line 1 of field "Nav")
          if getAt(liste,2)=0 then
            put empty into menuMsg
            exit repeat
          end if
      end case
      if menuMsg <> empty then
        do menuMsg
        set menuMsg = empty
      end if
      exit
    end if
  end repeat
end

--activation des raccourcis clavier
on touchesOn
  set touchesOn=1
end touchesOn

--dΘsactivation des raccourcis clavier
on touchesOff
  set touchesOn=0
end